*-----------------------------------------------------------------
*PGM.NAME:   MOVE.OLD.DATA
*PURPOSE:    TO MOVE DATA FROM R8 FILES TO R8.5 ACCOUNT
*AUTHOR:     BARKSDALE
*CREATED:    07/19/95
*-----------------------------------------------------------------
$INCLUDE BP.MASTER GEN.COM2
*
OPEN 'VOC' TO VOC ELSE ABORT 201,'VOC'
*
EXECUTE \SSELECT VOC WITH F1 "F]"\
*
EOF=0; NUM.READ=0; NUM.DONE=0
*
10 *
CRT CS
CRT @(0,25):"Enter letter indicating starting point...":
STARTPOINT=""; INPUT STARTPOINT
IF STARTPOINT MATCHES "1A" ELSE GO 10
*
LOOP
  READNEXT ID ELSE EOF=1
UNTIL EOF DO
  IF ID[1,1] GE STARTPOINT THEN
    GOSUB 100
  END
REPEAT
CRT @(0,22):CL:"Process complete...":
ANY=""; INPUT ANY
STOP
*
100 *
REC=""
REC<1>="Q"
REC<2>="TSM.OLD"
REC<3>=ID
WRITE REC ON VOC,"XFER"
CRT CS
CRT @(0,5):CL:"FILE:    ":ID:
CRT @(0,22):CL:"Enter C(copy), L(list), E(edit), R(resize), Q(quit) or <return>...":
RSP=""; INPUT RSP
BEGIN CASE
  CASE RSP="Q"
    EOF=1
  CASE RSP="C"
    REC=""
    REC<1>="PQ"
    REC<2>="HCOPY XFER * (I"
    REC<3>="STON"
    REC<4>="H(":ID
    WRITE REC ON VOC,"XFER2"
    EXECUTE \XFER2\
    CRT @(0,22):CR:ID:" file has been copied!":;RQM
  CASE RSP="L"
    EXECUTE \LIST XFER\
    CRT @(0,22):CR:"Press <return> to continue...":
    ANY=""; INPUT ANY
    GO 100
  CASE RSP="E"
    EXECUTE \ED XFER *\
    GO 100
  CASE RSP="R"
    EXECUTE \FILE.INFO XFER\
    INPUT DUMMY
    EXECUTE \FILE.INFO \:ID
    CRT @(0,22):"Resize this file (Y/N)":
    ANS=""; INPUT ANS
    IF ANS="Y" THEN
      CRT @(0,22):"Enter new modulo...":
      MODULO=""; INPUT MODULO
      EXECUTE \DELETE.FILE DATA \:ID
      EXECUTE \CREATE.FILE DATA \:ID:\ \:MODULO:\,4\
    END
    GO 100
END CASE
RETURN