$INCLUDE UNIVERSE.INCLUDE MTF.INCL.H
$INCLUDE UNIVERSE.INCLUDE FILENAMES.H
$INCLUDE UNIVERSE.INCLUDE MACHINE.NAME
$INCLUDE UNIVERSE.INCLUDE TLOG.H
******************************************************************************
*
*   System Admin Transaction Logging - Add Log Files
*
*	Module	%M%	Version	%I% 	Date	%H%
*
*	(c) Copyright 1998 Ardent Software Inc. - All Rights Reserved
*	This is unpublished proprietary source code of Ardent Software Inc.
*	The copyright notice above does not evidence any actual or intended
*	publication of such source code.
*
*******************************************************************************
*
*	Maintenence log - insert most recent change descriptions at top
*
*	Date.... GTAR# WHO Description........................................
*	10/14/98 23801 SAP Change copyrights. 
*	05/15/94 13286 DTM Initial Programming
*
*******************************************************************************
id = "%W%"
*******************************************************************************

*******************************************************************************
*	Call initialization routines
*******************************************************************************
TPRINT @(-1)

temp = NULL
CALL *ISUSER.B(0, temp)
IF temp = 0 THEN
    TPRINT UVREADMSG(071000,"")
    SLEEP 3
    STOP
END

PATH=""
RECIO( PATH, RECIO$PATH )

IF PATH = "" THEN
	message = "No Logging Directory Exists"
	CALL *HELP.BOX.B(3,10,40,message)
	STOP
END
GOSUB init.form
CALL *DRAW.SCRN.B( AFILE.MSG1, 1 )
GOSUB init.menu
CALL *MNU.BAR.PR.B(Menu.Bar,1)

*******************************************************************************
*	Begin processing
*******************************************************************************

CALL *HELP.PRINT.B(UVREADMSG(073009,""),2)
CALL *PUT.FORM.B(form.size,form,temp.form,PRMPT,1)

help.loop:

CALL *HELP.PRINT.B(form<form.line,4>,1)

input.loop:

TPRINT form<form.line,2>:
temp=temp.form<form.line>
CALL *CINPUT.B(SEC.PRMPT,temp,special,form<form.line,6>,0)

IF special # 0 THEN
	BEGIN CASE
		CASE special = UP.ARROW
			TPRINT form<form.line,2>:PRMPT:
            IF temp.form<form.line> # NULL THEN
                TPRINT temp.form<form.line>:
                TPRINT STR(SPACE,27-len(temp.form<form.line>)):
            END
            ELSE
                TPRINT group.defaults<form.line>:
                TPRINT STR(SPACE,27-len(group.defaults<form.line>)):
            END
            form.line -=1
            IF form.line < 1 THEN
                form.line = form.size
            END
            GOTO help.loop
		CASE special = DOWN.ARROW
            TPRINT form<form.line,2>:PRMPT:
            IF temp.form<form.line> # NULL THEN
                TPRINT temp.form<form.line>:
                TPRINT STR(SPACE,27-LEN(temp.form<form.line>)):
            END
            ELSE
                TPRINT group.defaults<form.line>:
                TPRINT STR(SPACE,27-LEN(group.defaults<form.line>)):
            END
            form.line +=1
            IF form.line > form.size  THEN
                form.line = 1
            END
            GOTO help.loop
		CASE special = F.1
			CALL *HELP.PRINT.B(form<1,5>,3)
			GOTO input.loop
		CASE special = ESCAPE
			STOP @(-1)
		CASE special = F.10
			action.value=1
			CALL *DO.MNU.BAR.B(Menu.Bar,action.value,form.size,form,temp.form)
			BEGIN CASE
				CASE action.value = 1
					STOP @(-1)
				CASE action.value = 2
					STOP @(-1)
				CASE action.value = 3
					message=AFILE.MSG6
					CONVERT @FM TO " " IN message
					CALL *HELP.BOX.B(3,10,60,message)
				CASE action.value = 4
					message=UVREADMSG(076001,"")
					CONVERT @FM TO " " IN message
					CALL *HELP.BOX.B(3,10,60,message)
				CASE action.value = 5
					CALL *HELP.BOX.B(3,10,45,UVREADMSG(076000,""))
			END CASE
			CALL *PUT.FORM.B(form.size,form,temp.form,PRMPT,1)
			GOTO help.loop
		CASE 1
			GOTO input.loop
	END CASE
END
ELSE
	BEGIN CASE
		CASE form.line = 1
			NumBytes	= temp
			IF NumBytes < 100000 THEN
				mess = "Minimum File size is 100k bytes"
				CALL *HELP.BOX.B(3, 10, 50, mess )
				temp.form< form.line > = 100000
    			TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    			TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
				GOTO help.loop
			END
			temp.form< form.line > = temp
		CASE form.line = 2
			NumFiles	= temp
			IF NumFiles < 1 THEN
				mess = "Minimum Number of Files is 1"
				CALL *HELP.BOX.B(3, 10, 50, mess )
				temp.form< form.line > = 1
    			TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    			TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
				GOTO help.loop
			END
			temp.form< form.line > = temp
	END CASE
    TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
    form.line+=1

	IF form.line <= form.size THEN
		GOTO help.loop
	END
	ELSE
		GOSUB add.log.file
	END
END
STOP @(-1)

*************************************************************************
*	add.log.file
*************************************************************************
add.log.file:
	Exec.Sentence = "CREATE.LFILE ":NumBytes:" ":NumFiles
	TPRINT @(-1)
	EXECUTE Exec.Sentence
	SLEEP 10
RETURN

*************************************************************************
*  Init.form 
*     This routine is used TO initialize the form TO be printed on the 
*     screen for data input.  It also sets up the default answers, if
*     any
*
*************************************************************************
init.form:
	MINIMUM.FILE.SIZE 	= ( BKSIZE * 1000 )
	MINIMUM.NUM.FILES 	= 3
	form				= NULL
	temp.form			= NULL
	temp.form<1>		= MINIMUM.FILE.SIZE
	temp.form<2>		= MINIMUM.NUM.FILES
	form.size			= 2
	form.line			= 1
	form<1,1>			= @(5,9)
	form<1,2>			= @(40,9)
	form<1,3>			= AFILE.MSG2
	form<1,4>			= AFILE.MSG3
	form<1,5>			= form<1,4>
	form<1,6>			= 10
	form<2,1>			= @(5,11)
	form<2,2>			= @(40,11)
	form<2,3>			= AFILE.MSG4
	form<2,4>			= AFILE.MSG5
	form<2,5>			= form<1,4>
	form<2,6>			= 36
	group.defaults 		= NULL
	group.defaults<1> 	= NULL
	group.defaults<2> 	= NULL
RETURN

***************************************************************************
* init.menu - initializes menu bar
***************************************************************************
init.menu:
	scratch=UVREADMSG(073087,"")
    Menu.Bar =	NULL
    Menu.Bar<1,1> = 3		;* Number of Items in Menu.Bar
    Menu.Bar<1,2> = 1		;* Line # on which to print the Menu Bar
* First Item
    Menu.Bar<2,1,1>=scratch<1>	;* SubMenu Title
    Menu.Bar<2,1,2>=1		;* # of items in SubMenu
* SubMenu #1
    Menu.Bar<2,2,1>=scratch<6>	;* SubMenu Item
    Menu.Bar<2,2,2>=1		;* Action Code (Returned to calling process)
    Menu.Bar<2,2,3>=scratch<7>
* Second Item
    Menu.Bar<3,1,1>=scratch<8>	;* SubMenu Title
    Menu.Bar<3,1,2>=1		;* # of items in SubMenu
* SubMenu #1
    Menu.Bar<3,2,1>=scratch<6>	;* SubMenu Item
    Menu.Bar<3,2,2>=2		;* Action Code
    Menu.Bar<3,2,3>=scratch<7>
	scratch=UVREADMSG(073089,"")
	Menu.Bar<4,1,1>=scratch<1>
	Menu.Bar<4,1,2>=3
	Menu.Bar<4,2,1>=scratch<2>
	Menu.Bar<4,2,2>=3
	Menu.Bar<4,2,3>=scratch<3>
	Menu.Bar<4,3,1>=scratch<4>
	Menu.Bar<4,3,2>=4
	Menu.Bar<4,3,3>=scratch<5>
	Menu.Bar<4,4,1>=scratch<6>
	Menu.Bar<4,4,2>=5
	Menu.Bar<4,4,3>=scratch<7>
RETURN
STOP @(-1)
END