$INCLUDE UNIVERSE.INCLUDE MTF.INCL.H
$INCLUDE UNIVERSE.INCLUDE FILENAMES.H
$INCLUDE UNIVERSE.INCLUDE MACHINE.NAME
$INCLUDE UNIVERSE.INCLUDE TLOG.H
******************************************************************************
*
*   System Admin Transaction Logging - Delete restored logs
*
*	Module	%M%	Version	%I% 	Date	%H%
*
*	(c) Copyright 1998 Ardent Software Inc. - All Rights Reserved
*	This is unpublished proprietary source code of Ardent Software Inc.
*	The copyright notice above does not evidence any actual or intended
*	publication of such source code.
*
*******************************************************************************
*
*	Maintenence log - insert most recent change descriptions at top
*
*	Date.... GTAR# WHO Description........................................
*	10/14/98 23801 SAP Change copyrights. 
*	03/09/95 15857 DTM Changed default log #
*	10/21/94 15162 DTM Changed messages
*	10/12/94 15101 DTM Changed length of log number field
*	05/15/94 13286 DTM Initial Programming
*
*******************************************************************************
id = "%W%"
*******************************************************************************

*******************************************************************************
*	Call initialization routines
*******************************************************************************
TPRINT @(-1)
temp = NULL
CALL *ISUSER.B(0, temp)
IF temp = 0 THEN
    TPRINT UVREADMSG(071000,"")
    SLEEP 3
    STOP
END
GOSUB init.form
CALL *DRAW.SCRN.B( RFM.MSG0, 1 )
GOSUB init.menu
CALL *MNU.BAR.PR.B(Menu.Bar,1)

*******************************************************************************
*	Begin processing
*******************************************************************************

CALL *HELP.PRINT.B(UVREADMSG(073009,""),2)
CALL *PUT.FORM.B(form.size,form,temp.form,PRMPT,1)

help.loop:

CALL *HELP.PRINT.B(form<form.line,4>,1)

input.loop:

TPRINT form<form.line,2>:
temp=temp.form<form.line>
CALL *CINPUT.B(SEC.PRMPT,temp,special,form<form.line,6>,0)

IF special # 0 THEN
	BEGIN CASE
		CASE special = UP.ARROW
			TPRINT form<form.line,2>:PRMPT:
            IF temp.form<form.line> # NULL THEN
                TPRINT temp.form<form.line>:
                TPRINT STR(SPACE,27-len(temp.form<form.line>)):
            END
            ELSE
                TPRINT group.defaults<form.line>:
                TPRINT STR(SPACE,27-len(group.defaults<form.line>)):
            END
            form.line -=1
            IF form.line < 1 THEN
                form.line = form.size
            END
            GOTO help.loop
		CASE special = DOWN.ARROW
            TPRINT form<form.line,2>:PRMPT:
            IF temp.form<form.line> # NULL THEN
                TPRINT temp.form<form.line>:
                TPRINT STR(SPACE,27-LEN(temp.form<form.line>)):
            END
            ELSE
                TPRINT group.defaults<form.line>:
                TPRINT STR(SPACE,27-LEN(group.defaults<form.line>)):
            END
            form.line +=1
            IF form.line > form.size  THEN
                form.line = 1
            END
            GOTO help.loop
		CASE special = F.1
			CALL *HELP.PRINT.B(form< form.line,5>,3)
			GOTO input.loop
		CASE special = ESCAPE
			STOP @(-1)
		CASE special = F.10
			action.value=1
			CALL *DO.MNU.BAR.B(Menu.Bar,action.value,form.size,form,temp.form)
			BEGIN CASE
				CASE action.value = 1
					STOP @(-1)
				CASE action.value = 2
					STOP @(-1)
				CASE action.value = 3
					message=UVREADMSG(073634,"")
					CONVERT @FM TO " " IN message
					CALL *HELP.BOX.B(3,10,60,message)
				CASE action.value = 4
					message=UVREADMSG(076001,"")
					CONVERT @FM TO " " IN message
					CALL *HELP.BOX.B(3,10,60,message)
				CASE action.value = 5
					CALL *HELP.BOX.B(3,10,45,UVREADMSG(076000,""))
			END CASE
			CALL *PUT.FORM.B(form.size,form,temp.form,PRMPT,1)
			GOTO help.loop
		CASE 1
			GOTO input.loop
	END CASE
END
ELSE
	BEGIN CASE
		CASE form.line = 1
			IF temp = NULL THEN
				CALL *HELP.PRINT.B( NULL, 3 )
				CALL *HELP.BOX.B( 17, 5, 30, "Must Enter First Log" )
				temp.form< form.line > = NULL
    			TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    			TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
				GOTO help.loop
			END
			FirstLog	= temp
			temp.form< form.line > = temp
		CASE form.line = 2
			IF temp = NULL THEN
				CALL *HELP.PRINT.B( NULL, 3 )
				CALL *HELP.BOX.B( 17, 5, 30, "Must Enter Last Log" )
				temp.form< form.line > = NULL
    			TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    			TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
				GOTO help.loop
			END
			LastLog  	= temp
			temp.form< form.line > = temp
		CASE form.line = 3
			Path		= temp
			temp.form< form.line > = temp
	END CASE
    TPRINT form<form.line,2>:PRMPT:temp.form<form.line>:
    TPRINT STR(SPACE,16-LEN(temp.form<form.line>)):
    form.line+=1

	IF form.line <= form.size THEN
		GOTO help.loop
	END
	ELSE
		GOSUB delete.file
	END
END
STOP @(-1)

*************************************************************************
*	delete.file
*************************************************************************
delete.file:
	reply = 1
	CALL *YES.NO.BOX.B( 11 ,"Are you sure you want to delete files", reply )
	IF reply THEN
		Exec.Sentence = "DEL.RFILE ":FirstLog:" ":LastLog:" ":Path
		TPRINT @(-1)
		EXECUTE Exec.Sentence 
		SLEEP 5
	END
RETURN

*************************************************************************
*  Init.form 
*     This routine is used TO initialize the form TO be printed on the 
*     screen for data input.  It also sets up the default answers, if
*     any
*
*************************************************************************
init.form:
	form				= NULL
	temp.form			= NULL
	temp.form<1>		= "1"
	temp.form<2>		= "1"
	form.size			= 3
	form.line			= 1
	form<1,1>			= @(5,8)
	form<1,2>			= @(40,8)
	form<1,3>			= "Number of First Log File to Delete"
	form<1,4>			= "Enter the number of the First Log File to Delete from Logging Directory"
	form<1,5>			= form<1,4>
	form<1,6>			= 9
	form<2,1>			= @(5,10)
	form<2,2>			= @(40,10)
	form<2,3>			= "Number of Last Log File to Delete"
	form<2,4>			= "Enter the number of the Last Log File to Delete from Logging Directory"
	form<2,5>			= form<2,4>
	form<2,6>			= 9
	form<3,1>			= @(5,12)
	form<3,2>			= @(40,12)
	form<3,3>			= "Pathname of the logging directory"
	form<3,4>			= "Enter the path name of the directory which contained the log files"
	Path = ""
	RECIO( Path, RECIO$PATH )
	form<3,5>			= form<2,4>
	temp.form<3>		= Path
	form<3,6>			= 35
	group.defaults 		= NULL
	group.defaults<1> 	= NULL
	group.defaults<2> 	= NULL
	group.defaults<3> 	= NULL
RETURN

***************************************************************************
* init.menu - initializes menu bar
***************************************************************************
init.menu:
	scratch=UVREADMSG(073087,"")
    Menu.Bar =	NULL
    Menu.Bar<1,1> = 3		;* Number of Items in Menu.Bar
    Menu.Bar<1,2> = 1		;* Line # on which to print the Menu Bar
* First Item
    Menu.Bar<2,1,1>=scratch<1>	;* SubMenu Title
    Menu.Bar<2,1,2>=1		;* # of items in SubMenu
* SubMenu #1
    Menu.Bar<2,2,1>=scratch<6>	;* SubMenu Item
    Menu.Bar<2,2,2>=1		;* Action Code (Returned to calling process)
    Menu.Bar<2,2,3>=scratch<7>
* Second Item
    Menu.Bar<3,1,1>=scratch<8>	;* SubMenu Title
    Menu.Bar<3,1,2>=1		;* # of items in SubMenu
* SubMenu #1
    Menu.Bar<3,2,1>=scratch<6>	;* SubMenu Item
    Menu.Bar<3,2,2>=2		;* Action Code
    Menu.Bar<3,2,3>=scratch<7>
	scratch=UVREADMSG(073089,"")
	Menu.Bar<4,1,1>=scratch<1>
	Menu.Bar<4,1,2>=3
	Menu.Bar<4,2,1>=scratch<2>
	Menu.Bar<4,2,2>=3
	Menu.Bar<4,2,3>=scratch<3>
	Menu.Bar<4,3,1>=scratch<4>
	Menu.Bar<4,3,2>=4
	Menu.Bar<4,3,3>=scratch<5>
	Menu.Bar<4,4,1>=scratch<6>
	Menu.Bar<4,4,2>=5
	Menu.Bar<4,4,3>=scratch<7>
RETURN
STOP @(-1)
END