*******************************************************************************
*
*	List GCI File
*
*	Module	%M%	Version	%I% 	Date	%H%
*
*	(c) Copyright 1998 Ardent Software Inc. - All Rights Reserved
*	This is unpublished proprietary source code of Ardent Software Inc.
*	The copyright notice above does not evidence any actual or intended
*	publication of such source code.
*
*******************************************************************************
*
*	Maintenence log - insert most recent change descriptions at top
*
*	Date.... GTAR# WHO Description.........................................
*	10/14/98 23801 SAP Change copyrights. 
*	03/25/96 18026 PGW For MS Win, allow GCI file name on command line
*	10/27/89 5273  DSC Exit when given XX et al
*	08/08/88 5264  JSM Added PRINTER RESET
*	08/08/88 5283  JSM Added check for GCI file.
*	07/25/88   -    -  Maintenence log purged at 5.2.1, see release 5.1.10.
*
*******************************************************************************
      
PROGRAM LIST.GCI

      ID = "@(#)%M%	%I%"

$INCLUDE UNIVERSE.INCLUDE FILENAMES.H
$INCLUDE UNIVERSE.INCLUDE MACHINE.NAME
*
      prompt ""
      CL  = @(-4)
      CL.ERR = @(0,23):CL
      EQU BELL TO CHAR(7)
      ERR = CL.ERR:BELL
      MSG1=ERR:'Unable to open the file - '
      MSG10=ERR:PROD.NAMEU:' General Calling Interface is not installed.'

      * You can specify the definition file by putting its name on the
      * command line, otherwise it defaults to 'GCI'
      CMD = CONVERT(" ", @FM, TRIM(@SENTENCE))
      DEF.FILE.NAME = CMD<4>
      IF DEF.FILE.NAME = "" THEN DEF.FILE.NAME = 'GCI'

1     OPEN '','DATA.TYPES' TO FVDATA.TYPES ELSE
         PRINT MSG10:
         INPUT Q: ; PRINT CL.ERR: ; STOP
      END
2     OPEN '',DEF.FILE.NAME TO FVGCI ELSE
         PRINT MSG1:DEF.FILE.NAME:
         INPUT Q: ; PRINT CL.ERR: ; STOP
      END
      print @( -1 )
      print @( 0, 0 ):"General Calling Interface Administration" : @( 71, 0 ) : "LIST.GCI":
      IF OS.TYPE = "UNIX" THEN
         print @(23, 1): "List the ":PROD.NAMEU:" GCI File":
      END ELSE
         print @(23, 1): "List GCI Definition File ":DEF.FILE.NAME
      END
      print @( 0, 2 ): str( "-", 79 ):
      print @( 0, 4 ): 
      PRINT @(0,22):"Enter 'LPTR' for printer or <CR> for screen display ":
      INPUT ANS
      IF ANS='XX' OR ANS='xx' OR ANS='X' OR ANS='x' THEN STOP
      IF ANS='LPTR' OR ANS='lptr' THEN
         PA=''
         PA<-1>='PTERM CASE NOINVERT'
         PA<-1>='SORT ':DEF.FILE.NAME:' BY LANG _'
         PA<-1>='<<R( ),Enter subroutine name or <CR> for all subroutines>> _'
         IF OS.TYPE = "UNIX" THEN
            HDR='HEADING "Listing of GCI Subroutines '
         END ELSE
            HDR='HEADING "Listing of GCI Definition File '
            HDR:="'F'"
         END         
         HDR:="  'L' "
         HDR:='" _'
         PA<-1>=HDR
         PA<-1>='LPTR'
         PA<-1>='PTERM CASE INVERT'
      END ELSE
         PA=''
         PA<-1>='PTERM CASE NOINVERT'
         PA<-1>='SORT ':DEF.FILE.NAME:' BY S.LANG _'
         PA<-1>='<<R( ),Enter subroutine name or <CR> for all subroutines>> _'
         IF OS.TYPE = "UNIX" THEN
            HDR='HEADING "Listing of GCI Subroutines '
         END ELSE
            HDR='HEADING "Listing of GCI Definition File '
            HDR:="'F'"
         END
         HDR:="  'L' "
         HDR:='"'
         PA<-1>=HDR
         PA<-1>='PTERM CASE INVERT'
      END
      PRINTER RESET
      EXECUTE PA
   END