********************************************************************************
*
*	Program to compile all of the dictionaries on an account.
*
*	Module	%M%	Version	%I% 	Date	%H%
*
*	(c) Copyright 1998 Ardent Software Inc. - All Rights Reserved
*	This is unpublished proprietary source code of Ardent Software Inc.
*	The copyright notice above does not evidence any actual or intended
*	publication of such source code.
*
*******************************************************************************
*
*	Maintenence log - insert most recent change descriptions at top
*
*	Date.... GTAR# WHO Description.........................................
*	10/14/98 23801 SAP Change copyrights. 
*	06/04/96 18438 JC  Port to NT
*	07/25/88   -    -  Maintenence log purged at 5.2.1, see release 5.1.10.
*
*******************************************************************************

$OPTIONS DEFAULT

      OPEN 'VOC' TO VOC ELSE STOP 'CANNOT OPEN VOC'
      DATAREC = 'PA'
      SELECT.ITEMS = 'SSELECT VOC WITH TYPE = "F" AND F2 NOT.MATCHING'
      SELECT.ITEMS := " '...\...' AND F2 NOT.MATCHING"
      SELECT.ITEMS := ' ".../..." AND F2 # "*" AND F2 # "" AND F3 NOT.MATCHING '
      SELECT.ITEMS := " '...\...' AND F3 NOT.MATCHING"
      SELECT.ITEMS := ' ".../..." AND F3 # ""'
      PRINT 'Select all the items in your VOC file that are local files'
      PRINT 'with local DICT files.'
      PRINT
      EXECUTE SELECT.ITEMS
      LOOP
         READNEXT ID ELSE ID = ''
      WHILE ID DO
         DATAREC<-1> = 'DISPLAY      - COMPILING ':ID:' -'
         DATAREC<-1> = 'CD ':ID
      REPEAT
      PRINT
      PRINT 'Write the paragraph COMPILE.DICTS.PA on the VOC file.'
      PRINT
      WRITE DATAREC ON VOC, 'COMPILE.DICTS.PA'
      PRINT 'Turn on the COMO file COMPILE.DICTS.'
      PRINT
      EXECUTE 'COMO ON COMPILE.DICTS'
      PRINT
      PRINT 'Execute the paragraph COMPILE.DICTS.PA.'
      PRINT
      EXECUTE 'COMPILE.DICTS.PA'
      EXECUTE 'COMO OFF'
      PRINT 'DONE.'