*******************************************************************************
*
*	Program to check all of the dictionaries on an account
*	and flag those that did not compile.  
*
*	Module	%M%	Version	%I% 	Date	%H%
*
*	(c) Copyright 1998 Ardent Software Inc. - All Rights Reserved
*	This is unpublished proprietary source code of Ardent Software Inc.
*	The copyright notice above does not evidence any actual or intended
*	publication of such source code.
*
*******************************************************************************
*
*	Maintenence log - insert most recent change descriptions at top
*
*	Date.... GTAR# WHO Description.........................................
*	10/14/98 23801 SAP Change copyrights. 
*	06/04/96 18438 JC  Port to NT
*	07/25/88   -    -  Maintenence log purged at 5.2.1, see release 5.1.10.
*
*******************************************************************************

$OPTIONS DEFAULT

      OPEN 'VOC' TO VOC ELSE STOP 'CANNOT OPEN VOC'
      DATAREC = 'PA'
      SELECT.ITEMS = "SSELECT VOC WITH TYPE = 'F' AND F2 NOT.MATCHING"
      SELECT.ITEMS := " '...\...' AND F2 NOT.MATCHING"
      SELECT.ITEMS := " '.../...' AND F2 # '*' AND F2 # '' AND F3 NOT.MATCHING "
      SELECT.ITEMS := " '...\...' AND F3 NOT.MATCHING"
      SELECT.ITEMS := " '.../...' AND F3 # '' TO 1"
      PRINT 'Select all the items in your VOC file that are local files'
      PRINT 'with local DICT files to Select List 1.'
      PRINT
      EXECUTE SELECT.ITEMS
      PRINT 'Now loop through each file, checking for any I-types that were not compiled.'
      LOOP
         READNEXT ID FROM 1 ELSE ID = ''
      WHILE ID DO
         PRINT
         PRINT 'Processing DICT ':ID
         SELECT.ITEMS = 'SSELECT DICT ':ID:' WITH F1 LIKE I... WITH NO F20'
         EXECUTE SELECT.ITEMS
         IF @SYSTEM.RETURN.CODE THEN
            ID.LIST = ''
            LOOP
               READNEXT ITEM.ID ELSE ITEM.ID = ''
            WHILE ITEM.ID DO
               ID.LIST := ' ' : ITEM.ID 
            REPEAT
            DATAREC <-1> = 'DISPLAY PROCESSING DICT ':ID:ID.LIST
            DATAREC <-1> = 'ED DICT ':ID:ID.LIST
            DATAREC <-1> = 'CD ':ID:ID.LIST
         END
      REPEAT
      PRINT
      PRINT 'Write the paragraph CHECK.DICTS on the VOC file.'
      PRINT
      WRITE DATAREC ON VOC, 'CHECK.DICTS'
      PRINT
      PRINT 'DONE.'